Win11 彻底关闭开始菜单中的 "推荐的项目"
Win11的开始菜单中，包含一个“推荐的项目”，对一些用户来说，这个区域占用了不少空间，想要去掉。使用这款小工具，Win11推荐项目设置器，可以方便的关闭和开启“推荐的项目”。对Win11专业版 / 教育版 / 企业版等多个版本都有效，对家庭版无效，有需要的小伙伴可以试试。将下面的代码复制进文本编辑器，另存成 .bat 文件，然后双击运行该文件，重启电脑或资源管理即可。chcp 936
@echo off
color 3f
mode con cols=80 lines=35
setlocal
title Win11推荐项目设置器 v1.0 by IT豪哥
:: 检查是否以管理员身份运行
openfiles >nul 2>&1
if %errorlevel% neq 0 (
echo 正在以管理员权限运行...
powershell -Command "Start-Process '%~f0' -Verb runAs"
exit /b
)
:menu
cls
echo.
echo ============================================
echo Win11推荐项目设置器 v1.0
echo ============================================
echo === 可快速关闭/开启 Windows 11 开始菜单中“推荐的项目”===
echo === @IT豪哥 2025年7月18日===
echo === https://www.ithaoge.cn/===
echo.
echo1. 关闭“推荐的项目”（隐藏“推荐”区域）
echo.
echo2. 启用“推荐的项目”（恢复默认显示）
echo.
echo3. 重启资源管理器（快速应用更改）
echo.
echo0. 退出
echo.
set /p choice= 请输入选项对应的数字 ，按回车键确认：
if "%choice%"=="1" goto disable
if "%choice%"=="2" goto enable
if "%choice%"=="3" goto restart
if "%choice%"=="0" exit
goto menu
:disable
echo 正在关闭推荐的项目...
reg add "HKLM\SOFTWARE\Policies\Microsoft\Windows\Explorer" /v HideRecommendedSection /t REG_DWORD /d 1 /f
reg add "HKLM\SOFTWARE\Microsoft\PolicyManager\current\device\Start" /v HideRecommendedSection /t REG_DWORD /d 1 /f
reg add "HKLM\SOFTWARE\Microsoft\PolicyManager\current\device\Education" /v IsEducationEnvironment /t REG_DWORD /d 1 /f
echo 操作完成。
pause
goto menu
:enable
echo 正在启用推荐的项目...
reg delete "HKLM\SOFTWARE\Policies\Microsoft\Windows\Explorer" /v HideRecommendedSection /f
reg delete "HKLM\SOFTWARE\Microsoft\PolicyManager\current\device\Start" /v HideRecommendedSection /f
reg delete "HKLM\SOFTWARE\Microsoft\PolicyManager\current\device\Education" /v IsEducationEnvironment /f
echo 操作完成。
pause
goto menu
:restart
echo 正在重启资源管理器...
taskkill /f /im explorer.exe >nul 2>&1
timeout /t 1 >nul
start explorer.exe
echo 资源管理器已重启，可重新打开开始菜单，查看设置是否生效。
pause
goto menu
懒人可直接下载此文件，此方案由 IT豪哥 提供
页:
[1]